Public Support

################################################################################

#

# ADTF CMake macros file

#

# Copyright © Audi Electronics Venture GmbH. All rights reserved.

#

################################################################################

#

# TODO Description 

#

################################################################################

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_add_post_build_install(\<name\>)</b>

#

# This command works only on windows with MSVC.

# It's automatically used by each adtf examples build target (executable, filter,

# service, ...) using the macros (adtf_add_executable,

# adtf_add_filter, ...).

# Cmake adds a post build event to each target, which will be executed directly after build AND

# installs the target binary. Different from the standard CMake install target,

# this will NOT include subdirectories.

#

# Arguments:

# \li \<name\>:

# The name of the target.

################################################################################

macro(adtf_add_post_build_install NAME)

    if(MSVC)

        add_custom_command(TARGET ${NAME} POST_BUILD COMMAND ${CMAKE_COMMAND} -DCMAKE_INSTALL_CONFIG_NAME=${CMAKE_CFG_INTDIR} -DCMAKE_INSTALL_LOCAL_ONLY=true -P cmake_install.cmake)

    else(MSVC)

        add_custom_command(TARGET ${NAME} POST_BUILD COMMAND ${CMAKE_COMMAND} -DCMAKE_INSTALL_CONFIG_NAME=${CMAKE_BUILD_TYPE} -DCMAKE_INSTALL_LOCAL_ONLY=true -P cmake_install.cmake)

    endif(MSVC)

endmacro(adtf_add_post_build_install NAME)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_add_plugin(\<name\> \<source1\> ... \<sourceN\>)</b>

#

# This command adds a new ADTF plugin target (a adtfplugin).

#

# Arguments:

# \li \<name\>:

# The name of the target

# \li \<sourceX\>:

# The source files of the target.

################################################################################

macro(adtf_add_plugin NAME)   

    add_library(${NAME} MODULE ${ARGN})

    set_target_properties(${NAME}

        PROPERTIES

        SUFFIX ".adtfplugin"

    )

    if(UNIX)

        set_target_properties(${NAME}

            PROPERTIES

            PREFIX ""

        )

    endif(UNIX)

    adtf_add_post_build_install(${NAME})

endmacro(adtf_add_plugin NAME)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_add_filter(\<name\> \<source1\> ... \<sourceN\>)</b>

#

# This command adds a new ADTF filter target (a adtfplugin file that contains filter 

# modules) and execute an install directly after build.

#

# Arguments:

# \li \<name\>:

# The name of the target

# \li \<sourceX\>:

# The source files of the target.

################################################################################

macro(adtf_add_filter NAME)

    adtf_add_plugin(${NAME} ${ARGN})

    target_link_libraries(${NAME} PUBLIC adtf::filtersdk)

endmacro(adtf_add_filter NAME)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_add_streaming_service(\<name\> \<source1\> ... \<sourceN\>)</b>

#

# This command adds a new ADTF streaming service target (a adtfplugin file that contains streaming service 

# modules) and execute an install directly after build.

#

# Arguments:

# \li \<name\>:

# The name of the target

# \li \<sourceX\>:

# The source files of the target.

################################################################################

macro(adtf_add_streaming_service NAME)

    adtf_add_plugin(${NAME} ${ARGN})

    target_link_libraries(${NAME} PUBLIC adtf::systemsdk)

endmacro(adtf_add_streaming_service NAME)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_add_system_service(\<name\> \<source1\> ... \<sourceN\>)</b>

#

# This command adds a new ADTF system service target (a adtfplugin file that contains a 

# system service module) and execute an install directly after build.

#

# Arguments:

# \li \<name\>:

# The name of the target

# \li \<sourceX\>:

# The source files of the target.

################################################################################

macro(adtf_add_system_service NAME)

    adtf_add_plugin(${NAME} ${ARGN})    

    target_link_libraries(${NAME} PUBLIC adtf::systemsdk)

endmacro(adtf_add_system_service NAME)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_add_executable(\<name\> \<source1\> ... \<sourceN\>)</b>

#

# This command adds a new ADTF service target (a adtfplugin file and a 

# exe file) and execute an install directly after build.

#

# Arguments:

# \li \<name\>:

# The name of the target

# \li \<sourceX\>:

# The source files of the target.

################################################################################

macro(adtf_add_executable NAME)

    add_executable(${NAME} ${ARGN})

    adtf_add_post_build_install(${NAME})

endmacro(adtf_add_executable NAME)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_install_target(\<target\> \<directory\>)</b>

#

# This command installs a target to the given location during

# installation.

#

# Arguments:

# \li \<target\>:

# The name of the target that should be installed.

# \li \<directory\>:

# The directory where the target should be installed to.

################################################################################

macro(adtf_install_target TARGET DIRECTORY)

    install(TARGETS ${TARGET} DESTINATION ${DIRECTORY}/debug CONFIGURATIONS Debug)

    install(TARGETS ${TARGET} DESTINATION ${DIRECTORY} CONFIGURATIONS Release RelWithDebInfo)

    if(WIN32)

        get_target_property(NAME ${TARGET} OUTPUT_NAME)

        if(NOT NAME)

            set(NAME ${TARGET})

        endif(NOT NAME)

        if(MSVC_IDE)

            set(PDB_FULL_PATH_DEBUG ${CMAKE_CURRENT_BINARY_DIR}/${${TARGET}_BUILD_NAME_}/Debug/${NAME}.pdb)

            install(FILES ${PDB_FULL_PATH_DEBUG} DESTINATION ${DIRECTORY}/debug CONFIGURATIONS Debug)

            set(PDB_FULL_PATH_RELWITHDEBINFO ${CMAKE_CURRENT_BINARY_DIR}/${${TARGET}_BUILD_NAME_}/RelWithDebInfo/${NAME}.pdb)

            install(FILES ${PDB_FULL_PATH_RELWITHDEBINFO} DESTINATION ${DIRECTORY} CONFIGURATIONS RelWithDebInfo)

        elseif()

            set(PDB_FULL_PATH ${CMAKE_CURRENT_BINARY_DIR}/${${TARGET}_BUILD_NAME_}/${NAME}.pdb)

            install(FILES ${PDB_FULL_PATH} DESTINATION ${DIRECTORY}/debug CONFIGURATIONS Debug)

            install(FILES ${PDB_FULL_PATH} DESTINATION ${DIRECTORY} CONFIGURATIONS RelWithDebInfo)

        endif()

    endif(WIN32)

endmacro(adtf_install_target TARGET DIRECTORY)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_install_plugin(\<target\> \<directory\>)</b>

#

# This command installs a filter or service module to the given location during

# installation. 

#

# Arguments:

# \li \<target\>:

# The name of the target that should be installed.

# \li \<directory\>:

# The directory where the target should be installed to.

################################################################################

macro(adtf_install_plugin TARGET DIRECTORY)

    adtf_install_target(${TARGET} ${DIRECTORY} ${ARGN})

endmacro(adtf_install_plugin TARGET DIRECTORY)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_install_plugin(\<target\> \<directory\>)</b>

#

# This command installs a filter or service module to the given location during

# installation. 

#

# Arguments:

# \li \<target\>:

# The name of the target that should be installed.

# \li \<directory\>:

# The directory where the target should be installed to.

################################################################################

macro(adtf_install_filter TARGET DIRECTORY)

    adtf_install_plugin(${TARGET} ${DIRECTORY} ${ARGN})

endmacro(adtf_install_filter TARGET DIRECTORY)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_install_plugin(\<target\> \<directory\>)</b>

#

# This command installs a filter or service module to the given location during

# installation. 

#

# Arguments:

# \li \<target\>:

# The name of the target that should be installed.

# \li \<directory\>:

# The directory where the target should be installed to.

################################################################################

macro(adtf_install_service TARGET DIRECTORY)

     adtf_install_plugin(${TARGET} ${DIRECTORY} ${ARGN})

endmacro(adtf_install_service TARGET DIRECTORY)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_install_program(\<target\> \<directory\>)</b>

#

# This command installs an executable to the given location during

# installation.

#

# Arguments:

# \li \<target\>:

# The name of the target that should be installed.

# \li \<directory\>:

# The directory where the target should be installed to.

################################################################################

macro(adtf_install_program TARGET DIRECTORY)

    adtf_install_target(${TARGET} ${DIRECTORY} ${ARGN})

endmacro(adtf_install_program TARGET DIRECTORY)

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_dev_add_qt_project_user_file(\<target_name\> \<exe_name\> \<working_dir_relative_debug\> 

#   \<working_dir_relative_release\>)</b>

#

# This command ...

#

# Arguments:

# \li \<target_name\>:

# The name of the poject file without extension. In most cases the

# TARGET_NAME

# \li \<exe_name\>:

# The name of the executable file without extension.

# \li \<working_dir_relative_debug\>:

# The directory to the debug executable file relative to ADTF_INSTALL_DIR. 

# Example: "bin/debug"

# \li \<working_dir_relative_release\>:

# The directory to the relwithdebinfo executable file relative to

# ADTF_INSTALL_DIR. Example: "bin"

################################################################################

function(adtf_dev_add_qt_project_user_file TARGET_NAME EXE_NAME

    WORKING_DIR_RELATIVE_DEBUG WORKING_DIR_RELATIVE_RELEASE) 

    if(NOT ADTF_INSTALL_DIR)

        message(SEND_ERROR "ADTF_INSTALL_DIR not set")

        RETURN()

    endif(NOT ADTF_INSTALL_DIR)

    set(COMMAND_DEBUG "${ADTF_INSTALL_DIR}/${WORKING_DIR_RELATIVE_DEBUG}/${EXE_NAME}.exe")

    set(WORKING_DIR_DEBUG "${ADTF_INSTALL_DIR}/${WORKING_DIR_RELATIVE_DEBUG}/")

    set(COMMAND_RELEASE "${ADTF_INSTALL_DIR}/${WORKING_DIR_RELATIVE_RELEASE}/${EXE_NAME}.exe")

    set(WORKING_DIR_RELEASE "${ADTF_INSTALL_DIR}/${WORKING_DIR_RELATIVE_RELEASE}/")

    vs_add_project_user_file("${TARGET_NAME}"

        "${COMMAND_DEBUG}"   " " "${WORKING_DIR_DEBUG}"   " "

        "${COMMAND_RELEASE}" " " "${WORKING_DIR_RELEASE}" " ")

endfunction()

################################################################################

## \page page_cmake_commands

# <hr>

# <b>vs_add_project_user_file(\<name\>

#   \<command_debug\> \<command_arguments_debug\> \<working_directory_debug\> 

#   \<environment_debug\> \<command_release\> \<command_arguments_release\> 

#   \<working_directory_release\> \<environment_release\> )</b>

#

# This command generates a *.vcxproj.user file and sets command, command 

# arguments and environment für build type "Debug" and "RelWithDebInfo"

#

################################################################################

function(vs_add_project_user_file NAME COMMAND_DEBUG COMMAND_ARGUMENTS_DEBUG 

    WORKING_DIRECTORY_DEBUG ENVIRONMENT_DEBUG COMMAND_RELEASE 

    COMMAND_ARGUMENTS_RELEASE WORKING_DIRECTORY_RELEASE ENVIRONMENT_RELEASE) 

    if(NOT MSVC_IDE)

        RETURN()

    endif(NOT MSVC_IDE)

    if(${NAME} STREQUAL "")

        message(SEND_ERROR "NAME not set")

        RETURN()

    endif(${NAME} STREQUAL "")

    # configure_file() ignores macro parameters. Therefore it is necessary to 

    # "reset" them - even if there ist no quot in.

    string(REPLACE "\"" """ COMMAND_DEBUG           ${COMMAND_DEBUG})

    string(REPLACE "\"" """ COMMAND_ARGUMENTS_DEBUG ${COMMAND_ARGUMENTS_DEBUG})

    string(REPLACE "\"" """ WORKING_DIRECTORY_DEBUG ${WORKING_DIRECTORY_DEBUG})

    string(REPLACE "\"" """ ENVIRONMENT_DEBUG       ${ENVIRONMENT_DEBUG})

    string(REPLACE "\"" """ COMMAND_RELEASE           ${COMMAND_RELEASE})

    string(REPLACE "\"" """ COMMAND_ARGUMENTS_RELEASE ${COMMAND_ARGUMENTS_RELEASE})

    string(REPLACE "\"" """ WORKING_DIRECTORY_RELEASE ${WORKING_DIRECTORY_RELEASE})

    string(REPLACE "\"" """ ENVIRONMENT_RELEASE       ${ENVIRONMENT_RELEASE})

    set(USER_FILENAME ${CMAKE_CURRENT_BINARY_DIR}/${NAME}.vcxproj.user)

    configure_file(${CMAKE_SOURCE_DIR}/bin/template.vcxproj.user.in ${USER_FILENAME} @ONLY)

endfunction()

################################################################################

## \page page_cmake_commands

# <hr>

# <b>adtf_find_sdl()</b>

#

# This command enables the use of SDL within ADTF. 

################################################################################

macro(adtf_find_sdl)

    find_package(SDL 1.2.11)

    if(SDL_FOUND)

        # On Windows platform SDL.dll must be installed with SDL dependent examples

        if(MSVC)

            set(SDL_DLL CACHE FILEPATH "SDL.dll will be installed with SDL dependent examples")

            if(NOT SDL_DLL)

                message(FATAL_ERROR "You need to set SDL_DLL in order to install SDL dependent examples")

            endif()

        endif()

    endif()

endmacro(adtf_find_sdl)

################################################################################

#

# This function ensures the creation of a plugindescription file for the given target by calling

# the PluginDescriptionGenerator as part of the build.

#

# Input Parameters:

#

# TARGET: The name of the target to generate the description for. This must be a ADTF plugin.

# PLUGIN_SUBDIR: The sub-directory of the given plugin within ADTF e.g. "examples/bin".

# MERGE_DESCRIPTION (optional): Path to an existing .plugindescription file which will be merged into the generated file.

# DEPENDENT_PLUGINS (optional): List of plugins which the given target depends on at runtime.

#

################################################################################

function(adtf_create_plugindescription)

    cmake_parse_arguments(PDGEN "" "TARGET;MERGE_DESCRIPTION;PLUGIN_SUBDIR" "DEPENDENT_PLUGINS" ${ARGN})

    if (NOT PDGEN_TARGET)

        message(FATAL_ERROR "Missing argument 'TARGET'.")

    endif()

    if (NOT TARGET ${PDGEN_TARGET})

        message(FATAL_ERROR "Unknown Target '${PDGEN_TARGET}'.")

    endif()

    if (NOT PDGEN_PLUGIN_SUBDIR)

        message(FATAL_ERROR "Missing argument 'PLUGIN_SUBDIR'. It should specify the directory of the plugin binary relative to CMAKE_INSTALL_PREFIX.")

    endif()

    if (PDGEN_MERGE_DESCRIPTION)

        if (NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${PDGEN_MERGE_DESCRIPTION})

            message(FATAL_ERROR "The plugin description file '${CMAKE_CURRENT_SOURCE_DIR}/${PDGEN_MERGE_DESCRIPTION}' does not seem to exist.")

        endif()

    endif()

    if (WIN32)

        set(EXE_SUFFIX .exe)

    endif()

    # Check if we're building ADTF or a client project (e.g. a toolbox).

    if (TARGET adtf_plugin_description_generator)

        set(IS_ADTF_CORE_BUILD TRUE)

    endif()

    # Set the path to the PDG executable accordingly.

    if (IS_ADTF_CORE_BUILD)

        set (PDGEN_ADTF_INSTALL_DIR ${CMAKE_INSTALL_PREFIX})

    else()

        set (PDGEN_ADTF_INSTALL_DIR ${ADTF_DIR})

    endif()

    set(PLUGINDESCRIPTION_GENERATOR "${PDGEN_ADTF_INSTALL_DIR}/bin/$<$<CONFIG:Debug>:debug/>adtf_plugin_description_generator${EXE_SUFFIX}")

    set(OUTPUT_PLUGINDESCRIPTION "${CMAKE_INSTALL_PREFIX}/${PDGEN_PLUGIN_SUBDIR}/$<$<CONFIG:Debug>:debug/>${PDGEN_TARGET}.plugindescription")

    if (DEFINED PDGEN_MERGE_DESCRIPTION)

        # Obtain the absolute path to the given .plugindescription file

        get_filename_component(MERGE_DESCRIPTION_PATH "${PDGEN_MERGE_DESCRIPTION}"

                       REALPATH BASE_DIR "${CMAKE_CURRENT_SOURCE_DIR}")

        set(MERGE_ARG "-merge=${MERGE_DESCRIPTION_PATH}")

    else()

        set(MERGE_ARG "")

    endif()

    # Set up build time dependencies to dependent targets.

    # If a dependency has a dedicated target for generating its plugindescription we use that one instead.

    if (DEFINED PDGEN_DEPENDENT_PLUGINS)

        foreach(DEPENDENT_PLUGIN IN LISTS ${PDGEN_DEPENDENT_PLUGINS})

            if (NOT TARGET ${DEPENDENT_PLUGIN})

                message(FATAL_ERROR "The dependent target ${DEPENDENT_PLUGIN} does not seem to exist.")

            endif()

            if (TARGET ${DEPENDENT_PLUGIN}_pdgen)

                add_dependencies(${PDGEN_TARGET} ${DEPENDENT_PLUGIN}_pdgen)

            else()

                add_dependencies(${PDGEN_TARGET} ${DEPENDENT_PLUGIN})

            endif()

        endforeach()

    endif()

    # Define a target <plugin_name>_pdgen which exectues the PluginDescriptionGenerator.

    add_custom_target(${PDGEN_TARGET}_pdgen ALL

        COMMAND

            ${PLUGINDESCRIPTION_GENERATOR}

            -plugin=$<TARGET_FILE:${PDGEN_TARGET}>

            -output=${OUTPUT_PLUGINDESCRIPTION}

            ${MERGE_ARG}

        COMMENT

            "Generating Plugin Description for Target ${PDGEN_TARGET}: ${PLUGINDESCRIPTION_GENERATOR} -plugin=$<TARGET_FILE:${PDGEN_TARGET}> -output=${OUTPUT_PLUGINDESCRIPTION} ${MERGE_ARG}"

        DEPENDS

            ${PDGEN_TARGET}

        SOURCES

            "${MERGE_DESCRIPTION_PATH}"

    )

    if (IS_ADTF_CORE_BUILD)

        add_dependencies(${PDGEN_TARGET}_pdgen adtf_plugin_description_generator)

    endif()

    # Put the generated target in the same IDE folder as the plugin's target.

    get_target_property(PLUGIN_IDE_FOLDER ${PDGEN_TARGET} FOLDER)

    if(PLUGIN_IDE_FOLDER)

        set_target_properties(${PDGEN_TARGET}_pdgen PROPERTIES FOLDER ${PLUGIN_IDE_FOLDER})

    endif()

endfunction(adtf_create_plugindescription)

################################################################################

## \page disable_msvc_warning

# <hr>

#

# This function disables a specific warning, <WARNING_NO_AS_STR>, for a specific target, 

# <TARGET_TO_DISABLE_>.

# Disabling takes only place for MSVC.

################################################################################

function(disable_msvc_warning TARGET_TO_DISABLE_ WARNING_NO_AS_STR)

    if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")

        set(DISBALE_WARNING_PREFIX "/wd")

        string(CONCAT DISABLE_WARNING_STR ${DISBALE_WARNING_PREFIX} ${WARNING_NO_AS_STR})

        target_compile_options(${TARGET_TO_DISABLE_} PRIVATE ${DISABLE_WARNING_STR})

    endif()

endfunction(disable_msvc_warning)